Typegist f543627

Manuals

The following manuals are available:

• The quick start should do so.
• The Typegist cookbook has a few conventions and gist definition recipes.
• The design notes explains a few design choices made by the library.

Library typegist

• Typegist Extended Stdlib.Type and Stdlib.Fun modules. Open to use it.
• Typegist.Type.Gist Type gists.
• Typegist.Fun.Generic Generic functions.

Quick start

The following shows how to define type gists for a simple data model for todo items. Among other Typegist.Fun.Generic functions this immediately gives us pretty-printing and random generation for testing. Other libraries may give you more, for example the jsont.typegist library derives JSON types from a type gists and thus provides JSON serialization out of the box for the data model.

open Typegist

module Status = struct
  type t = Todo | Done | Cancelled
  let enum = ["Todo", Todo; "Done", Done; "Cancelled", Cancelled ]
  let gist = Type.Gist.variant_of_enum ~name:"Status.t" enum
  let pp = Fun.Generic.pp gist
end

module Item = struct
  type t = { task : string; status : Status.t; tags : string list }
  let make task status tags = { task; status; tags }
  let task i = i.task
  let status i = i.status
  let tags i = i.tags
  let gist =
    Type.Gist.record "Item.t" make
    |> Type.Gist.field "task" Type.Gist.utf_8_string task
    |> Type.Gist.field "status" Status.gist status
    |> Type.Gist.field "tags" Type.Gist.(list utf_8_string) tags
    |> Type.Gist.finish

  let pp = Fun.Generic.pp gist
end

type items = Item.t list
let items_gist = Type.Gist.list ~name:"items" Item.gist

let random_items = Fun.Generic.random items_gist ()

If you find the randomness to be too arbitrary it is possible to influence the generation process by adding metadata to the description, see this cookbook entry.

The cookbook has more type gist modelling blueprints.